c
c User subroutine VUTRS for reduced time shift for viscoelastic materials
c     
      subroutine vutrs(
c Read only -
     *   nblock, nstatev, nfieldv, nprops, 
     *   stepTime, totalTime, dt, 
     *   cmname, props, density, coordMp, 
     *   tempOld, fieldOld, stateOld, 
     *   tempNew, fieldNew, 
c Write only -
     *   shift, stateNew )
c
      include 'vaba_param.inc'
c     
      dimension props(nprops), density(nblock), coordMp(nblock,*), 
     *   tempOld(nblock), tempNew(nblock),
     *   fieldOld(nblock,*), fieldNew(nblock,*),
     *   stateOld(nblock,*), stateNew(nblock,*),
     *   shift(nblock, 2)
c      
      character*80 cmname
c
      Tref  = props(1)
      C1    = props(2)
      C2    = props(3)
      Cln10 = 2.302585093d0
c
c     Use Williams-Landell-Ferry approximation
c
      do 100 k=1,nblock
         dTemp1 = tempOld(k) - Tref
         shift(k,1) = exp( -C1*Cln10*dTemp1 / (C2 + dTemp1) )
         dTemp2 = tempNew(k) - Tref
         shift(k,2) = exp( -C1*Cln10*dTemp2 / (C2 + dTemp2) )
  100 continue
c     
      return
      end